Sumário

# Funções de matriz

Essa categoria contém as funções de matriz.

## O que é uma matriz?

Uma matriz é um intervalo de células vinculado numa planilha contendo valores. Um intervalo quadrado de 3 linhas e 3 colunas é uma matriz 3 x 3:

| A | B | C | D | E
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50
4

A menor matriz possível é uma matriz 1 x 2 ou 2 x 1 com duas células adjacentes.

## O que é uma fórmula de matriz?

Uma fórmula na qual os valores individuais de um intervalo de células são avaliados é dita uma fórmula de matriz. A diferença entre uma fórmula de matriz e as outras fórmulas é que ela lida com diversos valores simultaneamente, e não com apenas um.

Uma fórmula de matriz pode processar, mas também retornar diversos valores. Os resultados de uma fórmula desse tipo também é uma matriz.

Para multiplicar os valores nas células individuais por 10 na matriz acima, você não precisa aplicar a fórmula para cada célula individual ou valor. No lugar disso, você só precisa usar uma única fórmula de matriz. Selecione um intervalo de 3 x 3 células em outro lugar da planilha, entre com a fórmula =10*A1:C3 e confirme esta entrada usando a combinação de teclas Command Ctrl+Shift+Enter. O resultado é uma matriz 3 x 3 na qual os valores individuais no intervalo de células (A1:C3) são multiplicados por um fator de 10.

Além da multiplicação, você também pode utilizar outros operadores no intervalo de referência (uma matriz). Com o LibreOffice Calc, você pode adicionar (+), subtrair (-), multiplicar (*), dividir (/), elevar a potências (^), concatenar (&) e efetuar comparações (=, <>, <, >, <=, >=). Os operadores poderão ser utilizados em cada valor individual do intervalo de células e retornarão o resultado na forma de matriz, caso a fórmula de matriz tiver sido inserida.

Operadores de comparação numa fórmula de matriz tratam as células vazias na mesma maneira que uma fórmula normal, isto é, tanto zero quanto texto vazio. Por exemplo, se as células A1 e A2 são vazias, as fórmulas de matriz {=A1:A2=""} e {=A1:A2=0} retornarão ambas uma matriz de 1 coluna e 2 linhas contendo o valor VERDADEIRO.

### Quando uma fórmula de matriz deve ser utilizada?

Utilize fórmulas de matriz caso tenha que repetir os mesmos cálculos utilizando valores diferentes. Se decidir alterar o método de cálculo posteriormente, você apenas precisará atualizar a fórmula de matriz. Para adicionar uma fórmula de matriz, selecione todo o intervalo da matriz e, em seguida, faça a alteração necessária na fórmula.

As fórmulas de matriz também poupam espaço quando diversos valores precisam ser calculados, pois não requerem muita memória. Além disso, matrizes são uma ferramenta essencial para efetuar cálculos complexos já que vários intervalos de células podem ser incluídos nos cálculos. O LibreOffice possui diversas funções matemáticas para matrizes, como a função MATRIZ.MULT, que multiplica duas matrizes, ou a função SOMARPRODUTO, que calcula o produto escalar de duas matrizes.

## Utilizar fórmulas de matriz no LibreOffice Calc

### Interseção implícita de fórmulas de matriz

Você também pode criar uma fórmula "normal" na qual o intervalo de referência, como os parâmetros, indica uma fórmula de matriz. Esta fórmula também é conhecida por "interseção implícita" de fórmula de matriz. O resultado é obtido a partir da interseção do intervalo de referência com as linhas ou as colunas nas quais a fórmula está localizada. Se não existir interseção ou se o intervalo da interseção abranger diversas linhas ou colunas, uma mensagem de erro #VALOR! será exibida. O exemplo a seguir ilustra esse conceito:

Na tabela acima, coloque a fórmula de matriz em D1:

{=A1:A3 + 100}

As células D1, D2, D3 têm valores 107, 195, 105 respectivamente.

Insira a fórmula abaixo em E2, sem inserir como fórmula de matriz.

=A1:A3 + 100

As células E1 e E3 estão vazias, a célula E2 tem o valor 195. Esta é a interseção implícita das fórmulas de matriz.

Insira a fórmula abaixo em E4, como em E2.

=A1:A3 + 100

A célula E4 exibe #VALOR!. A linha 4 está fora do intervalo A1:A3 da fórmula.

### Criar de fórmulas de matriz

Se criar uma fórmula de matriz usando o Assistente de funções, marque sempre a caixa de seleção Matriz, para que os resultados sejam retornados numa matriz. Caso contrário, somente o valor da célula superior esquerda da matriz calculada será retornado.

Se inserir uma fórmula de matriz diretamente na célula, você deve utilizar a combinação de teclas Shift + Command Ctrl + Enter em vez da tecla Enter. Somente então a fórmula se torna uma fórmula de matriz.

As fórmulas de matriz são exibidas entre chaves no LibreOffice Calc. Você não pode criar fórmulas de matriz inserindo as chaves manualmente.

As células de uma matriz de resultados estão automaticamente protegidas contra alterações. Entretanto, você pode editar, excluir ou copiar a fórmula de matriz selecionando todo o intervalo de células da matriz.

### Inserir matrizes de constantes em fórmulas

O Calc permite inserir matrizes/vetores de constantes em fórmulas. Uma matriz inserida na fórmula é envolta por chaves '{' e '}'. Os elementos da matriz podem ser números (incluindo negativos), constantes lógicas (VERDADEIRO, FALSO), ou texto literal. Expressões não constantes não são permitidas. As matrizes podem ser inseridas com uma ou mais linhas e uma ou mais colunas. Todas as linhas devem conter o mesmo número de elementos, todas as colunas devem conter o mesmo número de elementos.

O separador de coluna (que separa elementos numa linha) e o separador de linhas dependem do local e do idioma. Mas nesta ajuda, o ';' ponto-e-vírgula e a '|' barra vertical serão utilizados para indicar o separador de coluna e linha, respectivamente. Por exemplo, no local Inglês, a ',' vírgula é utilizada como separadora de coluna enquanto o ';' ponto-e-vírgula é utilizado como separador de linha.

Você pode ver e modificar os separadores de colunas e linhas em LibreOffice - Preferências Ferramentas - Opções - Calc - Fórmula - Separadores.

Matrizes não podem ser aninhadas.

Exemplos:

={1;2;3}

Uma matriz com uma linha, consistindo de três números 1, 2, e 3.

Para inserir essa matriz constante, selecione as três células na linha e digite a fórmula ={1;2;3} usando chaves e ponto-e-vírgula, em seguida pressione Command Ctrl + Shift + Enter.

={1;2;3|4;5;6}

Uma matriz com duas linhas e três valores em cada linha.

={0;1;2|FALSO;VERDADEIRO;"dois"}

Uma matriz com dados de vários tipos.

=SEN({1;2;3})

Quando inserido como fórmula de matriz, resulta em três cálculos do SEN com argumentos 1,2 e 3.

### Editar de fórmulas de matriz

1. Selecione o intervalo de células ou a matriz que contém a fórmula de matriz. Para selecionar a matriz inteira, posicione o cursor da célula dentro do intervalo da matriz e pressione Command Ctrl +/, onde / e a tecla Divisão no teclado numérico.

2. Pressione F2 ou posicione o cursor na linha de entrada. Ambas essas ações permitem editar a fórmula.

3. Pressione Command Ctrl+ Shift + Enter.

Você pode formatar as diferentes partes de uma matriz. Por exemplo, você pode alterar a cor da fonte. Selecione um intervalo de células e, em seguida, altere o atributo desejado.

### Excluir fórmulas de matriz

1. Selecione o intervalo de células ou a matriz que contém a fórmula de matriz. Para selecionar a matriz inteira, posicione o cursor da célula dentro do intervalo da matriz e pressione Command Ctrl +/, onde / e a tecla Divisão no teclado numérico.

2. Pressione Del para excluir o conteúdo da matriz, incluindo a fórmula matricial, ou pressione Backspace para trazer a caixa de diálogo Excluir conteúdo. Selecione Fórmula ou Excluir tudo e clique em OK.

### Copiar fórmulas de matriz

1. Selecione o intervalo de células ou a matriz que contém a fórmula de matriz.

2. Ou pressione F2 ou posicione o cursor na linha de entrada.

3. Copie a fórmula na linha de entrada pressionando Command Ctrl + C.

4. Selecione um intervalo de células no qual você deseja inserir a fórmula de matriz e pressione F2 ou posicione o cursor na linha de entrada.

5. Cole a fórmula pressionando Command Ctrl + V no espaço selecionado e confirme pressionando Command Ctrl + Shift + Enter. O intervalo selecionado agora contém a fórmula de matriz.

### Ajustar um intervalo de matriz

Para editar a matriz de saída, execute o seguinte procedimento:

1. Selecione o intervalo de células ou a matriz que contém a fórmula de matriz.

2. Na parte inferior direita da seleção, há um ícone pequeno que permite aplicar mais ou menos zoom ao intervalo utilizando o mouse.

Quando você ajusta o intervalo da matriz, a fórmula de matriz não é ajustada automaticamente. Somente o intervalo no qual o resultado será exibido é alterado.

Mantendo pressionado a tecla Command Ctrl, você pode criar uma cópia da fórmula de matriz no intervalo determinado.

### Cálculos condicionais de matrizes

Um cálculo condicional de matriz é uma fórmula de matriz que inclui uma função SE() ou ESCOLHER(). O argumento de condição na fórmula é uma referência de área ou o resultado de uma matriz.

No exemplo a seguir, o teste >0 da fórmula {=SE(A1:A3>0;"sim";"não")} é aplicado a cada célula do intervalo A1:A3 e o resultado é copiado para a célula correspondente.

| A | B (fórmula) | B (resultado)
1 | 1 | {=SE(A1:A3>0;"sim";"não")} | sim
2 | 0 | {=SE(A1:A3>0;"sim";"não")} | não
3 | 1 | {=SE(A1:A3>0;"sim";"não")} | sim

As funções a seguir forçam a utilização de matrizes: CORREL, COVAR, PREVISAO, TESTEF, INTERCEPÇÃO, MATRIZ.DETERM, MATRIZ.INVERSO, MATRIZ.MULT, MODO, PEARSON, PROB, RQUAD, INCLINAÇÃO, EPADYX, SOMARPRODUTO, SOMAX2DY2, SOMAX2SY2, SOMAXMY2, TESTET. Se utilizar referências de área como argumentos, quando você chamar uma dessas funções, elas se comportarão como funções de matriz. A tabela a seguir mostra um exemplo de utilização forçada de matriz:

| A | B (fórmula) | B (resultado) | C (fórmula forçada de matriz) | C (resultado)
1 | 1 | =A1:A2+1 | 2 | =SOMARPRODUTO(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SOMARPRODUTO(A1:A2+1) | 5
3 |  | =A1:A2+1 | #VALOR! | =SOMARPRODUTO(A1:A2+1) | 5

## CRESCIMENTO

Calcula os pontos de uma tendência exponencial numa matriz.

#### Sintaxe

CRESCIMENTO(DadosY [; [ DadosX ] [; [ NovosDadosX ] [; TipoFunção ] ] ] )

DadosY representa a matriz de dados Y.

DadosX (opcional) representa a matriz de dados X.

NovosDadosX (opcional) representa a matriz de dados X, cujos valores serão calculados.

TipoFunção (opcional). Se TipoFunção = 0, funções na forma y = m^x serão calculadas. Senão, funções y = b*m^x serão calculadas.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

Para obter mais explicações, consulte o início desta página.

#### Exemplo

Essa função retorna uma matriz e é tratada da mesma maneira que as outras funções de matriz. Selecione um intervalo onde você deseja que as respostas apareçam e selecione a função. Selecione DadosY. Entre com quaisquer outros parâmetros, marque Matriz e clique em OK.

## FREQUÊNCIA

Indica a distribuição de frequência numa matriz de uma coluna. A função conta o número dos valores na matriz Dados que está dentro dos valores dados pela matriz Classes.

#### Sintaxe

FREQUÊNCIA(Dados; Classes)

Dados representa a referência para os valores que serão contados.

Classes representa a matriz dos valores limites.

Esta função ignora qualquer texto ou célula vazia num intervalo de dados. Se suspeitar de resultados errados desta função, procure por texto nos intervalos de dados. Para destacar o conteúdo do texto num intervalo de dados, use o recurso destaque de valor .

Consulte o início desta página para obter uma introdução geral sobre funções de matriz.

#### Exemplo

Na tabela que segue, a coluna A contém valores de medidas não ordenadas. A coluna B contém o limite superior para as classes nas quais você quer dividir os dados na coluna A. De acordo com o limite inserido em B1, a função FREQUÊNCIA retorna o número de medidas menores ou iguais a 5. Como o limite em B2 é 10, a função FREQUÊNCIA retorna o segundo resultado como o número de medidas maiores que 5 e menores ou iguais a 10. O texto que você inseriu em B6, ">25", serve apenas como referência.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Selecione um único intervalo de colunas no qual será inserida a frequência de acordo com os limites das classes. Você deve selecionar um campo a mais que o teto da classe. Neste exemplo, selecione o intervalo C1:C6. Ative a função FREQUÊNCIA no Assistente de funções. Selecione o intervalo de Dados em (A1:A11), em seguida, o intervalo de Classes no qual você inseriu os limites de classe (B1:B6). Selecione a caixa de seleção Matriz e clique em OK. Você verá a contagem de frequência no intervalo C1:C6.

Para obter mais explicações, consulte o início desta página.

## MATRIZ.DETERM

Retorna o determinante de uma matriz. Esta função retorna um valor na célula atual, ou seja, não é necessário definir um intervalo para os resultados.

#### Sintaxe

MATRIZ.DETERM(Matriz)

Matriz representa uma matriz quadrada nos quais os determinantes serão definidos.

Consulte o início desta página para obter uma introdução geral sobre a utilização de funções de matriz.

Para obter mais explicações, consulte o início desta página.

## MATRIZ.INVERSO

Retorna a matriz inversa.

#### Sintaxe

MATRIZ.INVERSO(Matriz)

Matriz representa uma matriz quadrada que deverá ser invertida.

Para obter mais explicações, consulte o início desta página.

#### Exemplo

Selecione um intervalo quadrado e escolha a função MATRIZ.INVERSO. Selecione a matriz de saída, marque o campo Matriz e clique em OK.

## MATRIZ.MULT

Calcula a matriz produto de duas matrizes. O número de colunas da matriz 1 deve ser igual ao número de linhas da matriz 2. A matriz quadrada possui o mesmo número de linhas e colunas.

#### Sintaxe

MATRIZ.MULT(Matriz 1; Matriz 2)

Matriz 1 representa a primeira matriz utilizada no produto matricial.

Matriz 2 representa a segunda matriz com o mesmo número de linhas.

Para obter mais explicações, consulte o início desta página.

#### Exemplo

Selecione um intervalo quadrado. Escolha a função MATRIZ.MULT. Selecione a Matriz1 e, em seguida, Matriz2. Utilizando o Assistente de funções, marque a caixa de seleção Matriz. Clique em OK. A matriz de saída será exibida no primeiro intervalo selecionado.

## MATRIZ.UNIDADE

Retorna a matriz quadrada unitária de um tamanho determinado. A matriz unitária é uma matriz quadrada na qual os elementos da diagonal principal são iguais a 1 e todos os demais elementos da matriz são iguais a 0.

#### Sintaxe

MATRIZ.UNIDADE(Dimensões)

Dimensões refere-se ao tamanho da matriz unitária.

Consulte o início desta página para obter uma introdução geral sobre funções de matriz.

#### Exemplo

Selecione um intervalo quadrado da planilha, por exemplo, de A1 a E5.

Sem desfazer a seleção do intervalo, selecione a função MATRIZ.UNIDADE. Marque a caixa de seleção Matriz. Entre as dimensões desejadas da matriz unitária, neste caso 5, e clique em OK.

Você também pode inserir a fórmula =MUNIT(5) na última célula do intervalo selecionado (E5) e pressionar Shift + Command + Enter Shift + Ctrl + Enter.

Será exibida uma matriz unitária com o intervalo A1:E5.

Para obter mais explicações, consulte o início desta página.

## PROJ.LIN

Retorna uma tabela de estatísticas para uma linha reta que melhor se ajusta ao conjunto de dados.

#### Sintaxe

PROJ.LIN(Dados_Y [; Dados_X [; TipoLinear [; Estatísticas]]])

Dados_Y é uma linha única ou intervalo de coluna que especifica as coordenadas y do conjunto de pontos de dados.

Dados_X é uma linha única correspondente ou intervalo de coluna que especifica as coordenadas x. Se Dados_X for omitido, uma sequência numérica padrão 1, 2, 3, ..., n será considerada. Se houver mais de um conjunto de variáveis Dados_X pode ser um intervalo com múltiplas linhas e colunas correspondentes.

PROJ.LIN encontra uma linha reta y = a + bx que melhor se ajusta aos dados, utilizando a regressão linear (o método de "mínimos quadrados"). Com mais de um conjunto de variáveis, a linha reta é da forma y = a + b1x1 + b2x2 ... + bnxn.

Se o parâmetro TipoLinear for FALSO a reta encontrada passará pela origem, pois o coeficiente linear «a» será zero (y = bx). Se o parâmetro for omitido, TipoLinear é VERDADEIRO por padrão. Não necessariamente a reta passará pela origem.

Se Estatísticas for omitido ou FALSO somente a linha superior da tabela de estatísticas será retornada. Se VERDADEIRO, a tabela inteira será retornada.

PROJ.LIN retorna uma tabela (matriz) de estatísticas como abaixo e deve ser inserida como fórmula de matriz (por exemplo utilizando Command Ctrl + Shift + Enter em vez de Enter).

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

Para obter mais explicações, consulte o início desta página.

#### Exemplo

Essa função retorna uma matriz e é manipulada da mesma forma que as outras funções de matriz. Selecione um intervalo para as respostas e então a função. Selecione DadosY. Se desejar, você pode inserir outros parâmetros. Selecione Matriz e clique em OK.

Os resultados retornados pelo sistema (se Estatísticas = 0), serão no mínimo mostrar a inclinação da linha de regressão e a sua interseção com o eixo Y. Se Estatísticas não for igual a 0, outros valores serão exibidos.

### Outros resultados da função PROJ.LIN:

Veja os seguintes exemplos:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | Valor PROJ.LIN |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #N/D
5 | 7 | 12 | 108 |  | 13,21 | 4 | #N/D
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #N/D
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

A coluna A contém diversos valores X1, a coluna B possui vários valores X2 e a coluna C contém os valores Y. Esses valores já estão inseridos na planilha. Você agora configurou o intervalo E2:G6 na planilha e ativou o Assistente de Funções. Para que a função PROJ.LIN funcione, marque a caixa de seleção Matriz no Assistente de Funções. Em seguida, selecione os seguintes valores na planilha (ou insira-os através do teclado):

Dados_Y é C2:C8

Dados_X é A2:B8

TipoLinear e Estatísticas são ambos 1.

Assim que você clicar em OK, o LibreOffice Calc preencherá o exemplo acima com os valores da função PROJ.LIN, conforme mostrado no exemplo.

A fórmula na barra de Fórmula corresponde a cada célula da matriz PROJ.LIN {=PROJ.LIN(C2:C8;A2:B8;1;1)}.

Isso representa os valores calculados por PROJ.LIN

E2 e F2: Inclinação m da linha de regressão y=b+m*x para os valores x1 e x2. Os valores são dados na ordem reversa; isto é, a inclinação para x2 em E2 e a inclinação para x1 em F2.

G2: O ponto de interseção de b com o eixo Y.

E3 e F3: O erro padrão do valor de inclinação.

G3: O erro padrão da interceptação

E4: RQUAD

F4: O erro padrão da regressão calculada para o valor Y.

E5: O valor F a partir da análise de variância.

F5: Os graus de liberdade a partir da análise de variância.

E6: A soma do desvio ao quadrado dos valores Y estimados a partir de suas médias lineares.

F6: A soma do desvio ao quadrado do valor Y estimado a partir dos valores Y determinados.

Para obter mais explicações, consulte o início desta página.

## PROJ.LOG

Essa função calcula o ajuste dos dados inseridos como uma curva de regressão exponencial (y=b*m^x).

#### Sintaxe

PROJ.LOG(DadosY [; DadosY [; TipoFunção [; Estatísticas]]])

DadosY representa a matriz de dados Y.

DadosX (opcional) representa a matriz de dados X.

TipoFunção (opcional). Se TipoFunção = 0, funções na forma y = m^x serão calculadas. Senão, funções y = b*m^x serão calculadas.

Estatísticas (opcional). Se Estatísticas = 0, somente o coeficiente de regressão será calculado.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

Para obter mais explicações, consulte o início desta página.

#### Exemplo

Consulte PROJ.LIN. Entretanto, não será retornado a soma de quadrados.

## SOMARPRODUTO

Multiplica os elementos correspondentes das matrizes e retorna a soma desses produtos.

#### Sintaxe

SOMARPRODUTO(Vetor 1[; Vetor 2;][...;[Vetor 255]])

Vetor 1[; Vetor 2;][...;[Vetor 255]] representam vetores em que os elementos correspondentes devem ser multiplicados e em seguida somados.

Ao menos um vetor deve ser parte da lista de argumentos. Se somente um vetor for especificado, todos os elementos do vetor são somados. Se mais de um vetor for especificados, todos devem ter o mesmo número de elementos.

#### Exemplo

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SOMARPRODUTO(A1:B3;C1:D3) retorna 397.

Cálculo: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Você pode usar SOMARPRODUTO para calcular o produto escalar de dois vetores.

SOMARPRODUTO retorna um único número. Não é necessário inseri-la como uma função de matriz.

Para obter mais explicações, consulte o início desta página.

## SOMAX2DY2

Retorna a soma da diferença dos quadrados dos valores correspondentes de duas matrizes.

#### Sintaxe

SOMAX2DY2(MatrizX; MatrizY)

MatrizX representa a primeira matriz cujos elementos serão elevados ao quadrado e somados.

MatrizY representa a segunda matriz cujos elementos devem ser elevados ao quadrado e subtraídos.

Para obter mais explicações, consulte o início desta página.

## SOMAX2SY2

Retorna a soma da soma dos quadrados dos valores correspondentes de duas matrizes.

#### Sintaxe

SOMAX2SY2(MatrizX; MatrizY)

MatrizX representa a primeira matriz cujos elementos serão elevados ao quadrado e somados.

MatrizY representa a segunda matriz cujos elementos devem ser elevados ao quadrado e somados.

Para obter mais explicações, consulte o início desta página.

## SOMAXMY2

Soma os quadrados da variância entre os valores correspondentes de duas matrizes.

#### Sintaxe

SOMAXMY2(MatrizX; MatrizY)

MatrizX representa a primeira matriz cujos argumentos devem ser subtraídos e elevados ao quadrado.

MatrizY representa a segunda matriz cujos elementos devem ser subtraídos e elevados ao quadrado.

Para obter mais explicações, consulte o início desta página.

## TENDÊNCIA

Retorna os valores resultantes de uma tendência linear.

#### Sintaxe

TENDÊNCIA(DadosY [; DadosX [; NovosDadosX [; TipoLinear]]])

DadosY representa a matriz de dados Y.

DadosX (opcional) representa a matriz de dados X.

NovosDadosX (opcional) representa a matriz de dados X, que será usada para recalcular valores.

TipoLinear (Opcional). Se TipoLinear = 0 , então as linhas serão calculadas passando pelo ponto zero. Caso contrário, linhas deslocadas também serão calculadas. O padrão é TipoLinear <> 0.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

Para obter mais explicações, consulte o início desta página.

#### Exemplo

Selecione um intervalo da planilha no qual serão exibidos os dados da tendência. Escolha a função. Insira os dados de saída ou selecione-os com o mouse. Marque o campo Matriz, clique em OK. Serão exibidos os dados de tendência calculados a partir dos dados de saída.

## TRANSPOR

Transpõe as linhas e as colunas de uma matriz.

#### Sintaxe

TRANSPOR(Matriz)

Matriz representa a matriz na planilha que será transposta.

Consulte o início desta página para obter uma introdução geral sobre a utilização de funções de matriz.

#### Exemplo

Na planilha, selecione o intervalo no qual a matriz transposta poderá aparecer. Se a matriz original tiver n linhas e m colunas, o intervalo selecionado deverá possuir, no mínimo, m linhas e n colunas. Em seguida, insira a fórmula diretamente, selecione a matriz original e pressione as teclas Shift + Command + Enter Shift + Ctrl + Enter. Ou, se estiver utilizando o Assistente de funções, marque a caixa de seleção Matriz. A matriz transposta aparecerá no intervalo de destino selecionado e estará automaticamente protegida contra alterações.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

A tabela acima possui 2 linhas e 4 colunas. Para transpô-la, você deve selecionar 4 linhas e 2 colunas. Assumindo que você deseja transpor a tabela acima para o intervalo A7: B10 (4 linhas e 2 colunas), você deve selecionar todo o intervalo e, em seguida, digite o seguinte:

TRANSPOR(A1:D2)

Então assegure-se de inserir como fórmula de matriz com Shift + Command + Enter Shift + Ctrl + Enter. O resultado será o seguinte:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

Tópicos relacionados

Funções por categoria

♥ Doe para nosso projeto! ♥