Sumário

# Função StrConv

Converte uma string conforme especificado por um tipo de conversão.

Esta constante, função ou objeto se ativa com a instrução Option VBASupport 1 colocada antes do código executável do programa em um módulo.

### Sintaxe:

StrConv(string As String, Conversion As Integer, [ LCID ])

### Tipo de retorno:

String

### Parâmetros:

string : Qualquer expressão de string válida.

Conversão: O tipo de conversão a ser realizada, conforme definido na tabela abaixo.

Conversão | Valor | Descrição
--- | --- | ---
vbUpperCase | 1 | Converte caracteres Texto em maiúsculas.
vbLowerCase | 2 | Converte caracteres Texto em minúsculas.
vbProperCase | 3 | Converte a primeira letra de cada palavra em Texto em maiúsculas.
vbWide | 4 | Conversão de caractere narrow (half-width) em Texto caracter wide (full-width).
vbNarrow | 8 | Conversão de caracteres wide (full-width) para Texto caracteres narrow (half-width)
vbKatakana | 16 | Converte caracteres Hiragana em Texto em caracteres Katakana.
vbHiragana | 32 | Converte caracteres Katakana em Texto em caracteres Hiragana.
vbUnicode | 64 | Converte caracteres Texto em caracteres Unicode usando a página de código padrão do sistema.
vbFromUnicode | 128 | Converte caracteres Texto de Unicode para a página de código padrão do sistema.

LCID Opcional. O ID da localidade em número decimal. Se este parâmetro for omitido, ele assumirá o ID local do sistema. Consulte o arquivo msi-encodinglist.txt para os valores LCID disponíveis.

### Exemplo:

    Option VBASupport 1
    Option Explicit
    Sub Test_StrConv
        Print StrConv("abc EFG hij", vbUpperCase) '= "ABC EFG HIJ"
        Print StrConv("abc EFG hij", vbLowerCase) ' =  "abc efg hij"
        Print StrConv("abc EFG hij", vbProperCase) ' = "Abc Efg Hij"

        REM Converte narrow caracteres (byte único) em string para caracteres wide.
        Print StrConv("ABCDEVB¥ì¥¹¥¥å©", vbWide) ' = "ＡＢＣＤＥＶＢ￥ì￥¹￥￥å©"

        REM Converte caracteres wide (byte duplo) em string para caracteres narrow (byte único).
        Print StrConv("ＡＢＣＤ＠＄％２３＇？ＥＧ", vbNarrow) ' = "ABCD@$%23'?EG"

        REM Converte caracteres Hiragana em string em caracteres Katakana.
        Print StrConv("かたかな", vbKatakana) ' = "カタカナ"

        REM Converte caracteres Katakana em string em caracteres Hiragana.
        Print StrConv("カタカナ", vbHiragana) '= "かたかな"

        REM assume-se a codificação CP-1252 associada à localidade en-US usada em unidades de testes.
        Dim x() As Byte
        x = StrConv("ÉÏº£ÊÐABC", vbFromUnicode)
        Print UBound(x) ' 8 caracteres
        Print x(2) ' = 186
        Print StrConv(x, vbUnicode)' = "ÉÏº£ÊÐABC"
    End Sub

Tópicos relacionados

Funções e Instruções VBA exclusivas

♥ Doe para nosso projeto! ♥